;:ifpeek(36865)+peek(36866)<>238thenload"profi-ass
;:open2,8,15,"s:code":close2
;:open2,8,2,"code,p,w
;:sys36864
	;.opt o2
	*= 3273
blt	=15000
dat	=blt+32
mea	=dat+14
mee	=40960
mel	=mee-mea
show	=blt+26
auto	=blt+27
de1	=blt+28
de2	=blt+29
de3	=blt+30
bar	=blt+31
tmp	=166
tmp2	=168
fld	=2
c1	=15
c2	=11
zs	=61440
bs	=52224
mem1	=40960
mem2	=51776
qq3	=1024
za	=208
sp	=26
xmk	=7
ymk	=8
chr	=15
dig	=12
unten	=bs+960
fun	=56256
men	=247
h1	=248
h2	=249
h3	=250
h4	=252
h5	=253
zei	=181
cx	=170
cy	=171
x	=176
y	=177
bx	=178
bl	=179
flg	=146
lin	=150
spa	=151
lli	=155
bre	=156
hn	=820
buf	=823
nbf	=180
flp1	=704
flp2	=flp1+5
flp3	=flp2+5
typ1	=189
typ2	=190
dp	=195
an	=191
lg	=196
errn	=159
rf	=158
m	=139
x1	=63
y1	=64
x2	=65
y2	=66
nr	=69
az	=70
af	=165
iz	=164
	jsr new
	jmp start
	.byte "  fuer birgit  "
tt	.byte "\x1a\x13\x08\x12\xa7\xa8\xa9\xaa\xab\xa8 \xac\xa8\xad\xa8 V2\x19\x03 von Nikolaus M. Heusler\x19\x1e"
	.byte " frei:\x19\x04 %\x03"
wt1	.byte "\x13\x1a\x19\x05\x11\x19\x0b\x1d\xb3\x19\x13\xb1\xb4\x03"
wt2	.byte "\x1a\x19\x0b\x1d\xb2\x19\x13 \xb2\x03"
wt3	.byte "\x1a\x19\x0b\x1d\xb5\x19\x13\xb1\xb6\x19\x0c\x91\x19\x13\x9d\x03"
wt4	.byte "\x13\x1a\x19\x03\x11\x19\x04\x1d\xb3\x19!\xb1\xb4\x03"
wt5	.byte "\x1a\x19\x04\x1d\xb2\x19! \xb2\x03"
wt6	.byte "\x1a\x19\x04\x1d\xb5\x19!\xb1\xb6\x13\x19\x06\x11\x19\x06\x1d\x03"
t1	.byte "\x17Felder werden neu berechnet\x03"
inf	.byte " in Feld \x03"
t2	.byte "\x18\x19\x05\x11 Sind Sie sicher?\x03"
t3	.byte "\x17Spaltenbreite? \x03"
t4	.byte "\x17Automatisches Nachrechnen \x03"
t5	.byte "\x17Formelausgabe \x03"
t6	.byte "\x17Anzahl der Nachkommastellen? \x03"
aat	.byte "einaus"
t7	.byte "koordinate falscH"
t8	.byte "\x17Gehe zu Feld \x03"
t9	.byte "\x17Titel? \x03"
ta	.byte "feld leeR"
tb	.byte "fehleingabE"
tc	.byte "\x17Tausenderpunkte \x03"
td	.byte "textfeld verboteN"
te	.byte "\x17Farbnummer \x03"
tf	.byte "(J/N) ?\x03"
tg	.byte "\x17Diskbefehl: \x03"
th	.byte "\x17Dateiname? \x03"
ti	.byte "speicher leeR"
tj	.byte "speicher volL"
tk	.byte "operator unbekannT"
tl	.byte "bereich leeR"
tm	.byte "drucker nicht bereiT"
cc	.byte "\x18\x11\x1d\xa7\xa8\xa9\xaa\xab\xa8 \xac\xa8\xad\xa8 C64"
	.byte "\x16\x11Tabellenkalkulation"
	.byte "\x16Vers. #2, Update 35"
	.byte "\x16\x11@ Nikolaus Heusler"
	.byte "\x16  Zwengauerweg  18"
	.byte "\x16  D- 81479 M\xa5nchen"
	.byte "\x16\x11@ nh 01.94 a.r.r.\x03"
mt	.word men1,men2,men3,men4,men5,men6,men7,men8
	.word men9,men10,men11,men12,men13
mf	.byt 0,0,1,0,0,1,1,1,1,1,0,1,1
men1	.byte "titel  gehezu disk   rechne."
	.byte "druck  darst  l\xa3sche ende  "
men2	.byte "\xa1      \xa3      \xa5      \xae      "
	.byte "\xa2      \xa4      \xa6      @     "
men3	.byte "ja                   nein ."
men6	.byte "diese  alle          zur\xa6ck"
men4	.byte "aut.nr global einzel spalte."
	.byte "formel typ    tabstr zur\xa6ck"
men5	.byte "farbe  tauspk posit. zahlen."
	.byte "                     zur\xa6ck"
men7	.byte "feld   alles         zur\xa6ck"
men8	.byte "links  rechts mitte  zur\xa6ck"
men9	.byte "festko maximu intege zur\xa6ck"
men10	.byte "text   wert   beide  zur\xa6ck"
men11	.byte "laden  speich inhalt befehl."
	.byte "                     zur\xa6ck"
men12	.byte "weiter               zur\xa6ck"
men13	.byte "normal iterat        zur\xa6ck"
umlaut	.byt 161,163,165,174,162,164,166,64
umreal	.byte "aAoOuU"
mentxt	.byte " \x11\x91\x1d\x9d\x13\x93\x88\x8c\x8a\x86\x85\x8b\x87\x89"
menadr	.word space,down,up,right,left,home,unhom
	.word dorech,ende,darst,goto,day,clr,disk,print
dirn	.byte "$"
optab	.byt 170,173,179,177,35,172
artt	.byte "reeltxettrew"
delt	.byte "\x9d \x9d\x03"
fmax	.byt -1,$7f,-1,-1,$f8
fax1	.byte "Tabula Rasa V2   von N.Heusler   Ar"
	.byte "beitsblatt: "
	brk
strout	tax
	lda tmp
	pha
	lda tmp+1
	pha
	stx tmp
	sty tmp+1
su1	ldy #0
	lda (tmp),y
	beq su2
	cmp #"\x03"
	beq su2
	cmp #"\x1a"
	bne su3
	lda #13
su3	cmp #"\x19"
	beq su4
	cmp #"\x18"
	beq su5
	cmp #"\x17"
	beq su10
	cmp #"\x16"
	beq su11
	jsr $ffd2
su6	inc tmp
	bne su1
su8	inc tmp+1
	bne su1
su2	pla
	sta tmp+1
	pla
	sta tmp
	rts
su4	iny
	lda (tmp),y
	tax
	iny
	lda (tmp),y
su7	jsr $ffd2
	dex
	bne su7
	lda #3
	clc
	adc tmp
	sta tmp
	bcc su1
	bcs su8
su5	lda tmp
	pha
	lda #<wt1
	ldy #>wt1
	jsr strout
	lda #12
	sta tmp
su9	lda #<wt2
	ldy #>wt2
	jsr strout
	dec tmp
	bne su9
	pla
	sta tmp
	lda #<wt3
	ldy #>wt3
	jsr strout
	jmp su6
su10	jsr input2
	lda #0
	sta 199
	jmp su6
su11	jsr $aad7
	lda #12
	sta 211
	bne su6
crsr	lda cx
	clc
	adc x
	tay
	dey
	lda cy
	clc
	adc y
	tax
	dex
	rts
sout	stx xmk
	sta chr
	cmp #128
	bcs so1
	cmp #32
	bcc so2
	cmp #96
	bcc so3
	and #$df
	.byt $2c
so3	and #$3f
	.byt $2c
so2	ora #128
so4	ldy 199
	beq so7
	ora #128
so7	tay
	jsr $ea24
	ldx 211
	cpx #40
	bcs so5
	tya
	ldx 646
	jsr $ea13
	inc 211
so5	lda chr
	ldx xmk
	rts
so1	and #127
	cmp #127
	bne so6
	lda #$5e
so6	cmp #32
	ora #$40
	bcs so4
	bcc so2
clreol	ldy 211
	cpy #40
	bcs ce1
	ldx #c2
	pha
	jsr $ea13
	pla
	inc 211
	bne clreol
ce1	rts
inzei	sta (zei),y
	iny
	rts
m0	lda #0
	sta men
	rts
aa	ldx #0
	and #-1
	bne aa1
	ldx #3
aa1	ldy #3
aa2	lda aat,x
	jsr $ffd2
	inx
	dey
	bne aa2
	jsr m0
getk	lda #0
	sta 198
gk	cmp 198
	beq gk
	jmp $f146
ascii	stx xmk
	tax
	lda qq3,x
	sta dig
	lda qq3+256,x
	sta dig+1
	lda qq3+512,x
	sta dig+2
	ldx xmk
	rts
calc	jsr ram
	lda mem2,x
	sta tmp
	lda mem2+za,x
	sta tmp+1
	tya
	asl
	tay
	lda (tmp),y
	sta fld
	iny
	lda (tmp),y
	sta fld+1
	rts
val	jsr ram
	ldx #0
vd1	lda mem2,x
	sta tmp
	lda mem2+za,x
	sta tmp+1
	ldy #(sp*2)-1
	lda #0
vd2	sta (tmp),y
	dey
	bpl vd2
	inx
	cpx #za
	bcc vd1
	lda #<mea
	ldy #>mea
	sta zei
	sty zei+1
vd3	ldy #0
	lda (zei),y
	bne vd4
rom	lda #55
	sta 1
	cli
	rts
ram	sei
	lda #48
	sta 1
	rts
vd4	tax
	dex
	lda mem2,x
	sta tmp
	lda mem2+za,x
	sta tmp+1
	iny
	lda (zei),y
	sec
	sbc #1
	asl
	tay
	lda zei
	sta (tmp),y
	iny
	lda zei+1
	sta (tmp),y
	ldy #8
vd5	iny
	lda (zei),y
	bne vd5
	iny
	tya
	clc
	adc zei
	sta zei
	bcc vd3
	inc zei+1
	bne vd3
cuca	lda bar
	beq cc3
	lda #1
cc3	sta tmp
	ldx x
	ldy cx
	iny
	lda #3
cc1	dey
	beq cc2
	clc
	adc blt-1,x
	adc tmp
	inx
	cpx #sp+1
	bcc cc1
cc2	sta bx
	lda blt-1,x
	sta bl
	rts
cursor	lda cy
	clc
	adc #4
	tax
	jsr $e9f0
	ldy bx
	tya
	clc
	adc bl
	cmp #41
	bcs cu1
	ldx bl
cu2	lda ($d1),y
	eor #128
	sta ($d1),y
	iny
	dex
	bne cu2
	clc
cu1	rts
free	jsr val
	lda #<mee
	sec
	sbc zei
	tax
	lda #>mee
	sbc zei+1
	jsr axfac
	jsr $bc0c
	ldx #<mel
	lda #>mel
	jsr axfac
	jsr $bb14
	jsr $bae2
	jsr $bae2
	jsr $b849
	jsr $bc9b
	lda $65
	jsr ascii
	lda dig
	ora #128
	sta bs+76
	lda dig+1
	ora #128
	sta bs+77
	lda dig+2
	ora #128
	sta bs+78
	rts
axfac	sta $62
	stx $63
	ldx #$90
	sec
	jmp $bc49
clrfac	lda #0
	ldx #10
cf	sta $5d,x
	dex
	bpl cf
	rts
f1fac	lda #<flp1
	.byt $2c
f2fac	lda #<flp2
	ldy #>flp1
	jmp $bba2
irq	jsr showf
	jmp $ea31
showf	ldx men
	bne sh2
	stx h3
	stx h3+1
	inx
	stx h5
	bne sh1
sh2	lda mf-1,x
	sta h5
	txa
	asl
	tax
	lda mt-2,x
	sta h3
	lda mt-1,x
	sta h3+1
sh1	ldy #39
	lda #c2
sh3	sta fun,y
	dey
	bpl sh3
	ldx #120
	lda 653
	and #3
	beq sh4
	lda h5
	bne sh4
	ldx #124
	lda #28
	clc
	adc h3
	sta h3
	bcc sh4
	inc h3+1
sh4	stx h1
	ldx #0
	ldy #0
	sty h2
sh5	tya
	bne sh6
	lda #119
	bne sh7
sh6	cpy #1
	bne sh8
	lda h1
	inc h1
	bne sh7
sh8	cpy #2
	bne sha
	lda #58
	.byt $2c
shc	lda #32
	jmp sh7
sha	lda h3+1
	beq shc
	sty h4
	ldy h2
	lda (h3),y
	cmp #128
	bcs shd
	and #63
	.byt $2c
shd	sbc #64
	inc h2
	ldy h4
sh7	sta unten,x
	iny
	cpy #10
	bcc sh9
	ldy #0
sh9	inx
	cpx #39
	bcc sh5
	rts
out	ldx #219
	stx bs+120
	inx
	stx bs+121
	inx
	stx bs+122
	ldx #19
	lda #c2
	sta 646
	lda #<bs+160
	ldy #>bs+160
	sta tmp
	sty tmp+1
	ldy y
ou1	sty ymk
	lda qq3,y
	ora #128
	ldy #0
	sta (tmp),y
	ldy ymk
	lda qq3+256,y
	ora #128
	ldy #1
	sta (tmp),y
	ldy ymk
	lda qq3+512,y
	ora #128
	ldy #2
	sta (tmp),y
	lda #40
	clc
	adc tmp
	sta tmp
	bcc ou2
	inc tmp+1
ou2	ldy ymk
	iny
	dex
	bpl ou1
	ldx #3
	stx 211
	jsr $e9f0
	sta 199
	ldx x
ou3	lda blt-1,x
	tay
	clc
	adc #1
	lsr
	sta tmp
ou4	dec tmp
	bne ou5
	txa
	ora #192
	.byt $2c
ou5	lda #32
	stx xmk
	sty ymk
	jsr sout
	bcs ou6
	ldy ymk
	ldx xmk
	dey
	bne ou4
	lda bar
	beq ou7
	lda #175
	jsr sout
	bcs ou6
ou7	ldx xmk
	inx
	cpx #sp+1
	bcc ou3
	lda #160
	jsr clreol
ou6	lda #0
	sta 199
	lda y
	sta lin
	clc
	adc #20
	sta lli
	ldx #3
	jsr $e9f0
ou8	lda $d1
	clc
	adc #40
	sta $d1
	bcc oue
	inc $d2
oue	lda #3
	sta 211
	ldy x
ou9	sty spa
	dey
	lda blt,y
	sta bre
	ldx lin
	dex
	jsr calc
	bne noua
	jmp oua
noua	jsr rom
	ldy #8
	lda (fld),y
	and #15
	sta 646
	lda show
	bne oug
	ldy #7
	lda (fld),y
	bmi ouf
oug	ldy #8
	ldx #-1
sa1	inx
	iny
	lda (fld),y
	sta buf,x
	bne sa1
	beq oui
ouf	jsr werts
	ldx #-1
ouj	inx
oui	cpx bre
	bcs ouk
	lda buf,x
	bne ouj
	ldy #8
	lda (fld),y
	and #%110000
	beq oun
	cmp #%10000
	beq oul
	lda #32
oum	sta buf,x
	inx
	cpx bre
	bcc oum
	bcs ouk
oul	ldy bre
ouo	lda buf,x
	sta buf,y
	dey
	dex
	bpl ouo
	lda #32
oup	sta buf,y
	dey
	bpl oup
	bmi ouk
oun	txa
	clc
	adc bre
	lsr
	tay
	pha
ouq	lda buf,x
	sta buf,y
	dey
	dex
	bpl ouq
	lda #32
our	sta buf,y
	dey
	bpl our
	pla
	tay
	dey
	lda #32
ous	iny
	cpy bre
	bcs ouk
	sta buf,y
	bcc ous
ouk	ldx #0
ouu	lda buf,x
	jsr sout
	bcs ouc
	inx
	cpx bre
	bcc ouu
	bcs ouh
oua	jsr rom
	lda #32
	ldx bre
oub	jsr sout
	bcs ouc
	dex
	bne oub
ouh	lda #c2
	sta 646
	lda bar
	beq oud
	lda #175
	jsr sout
	bcs ouc
oud	ldy spa
	iny
	cpy #sp+1
	bcc qou9
	lda #112
	jsr clreol
ouc	inc lin
	lda lin
	cmp lli
	bcc qou8
	jmp rom
qou9	jmp ou9
qou8	jmp ou8
werts	and #64
	bne ws1
	lda #"?"
	sta buf
	lda #0
	sta buf+1
	rts
ws1	ldy #7
	lda (fld),y
	sta typ1
	iny
	lda (fld),y
	and #192
	sta typ2
	lda fld
	clc
	adc #2
	tax
	lda fld+1
	adc #0
	tay
	txa
	jsr $bba2
	lda typ2
	bne ws4
	jsr $bccc
	jmp ws3
ws4	cmp #64
	beq ws3
	ldx #<flp1
	ldy #>flp1
	jsr $bbd4
	lda typ1
	and #31
	sta an
	jsr $bc3c
	lda #$f9
	ldy #$ba
	jsr $ba8c
	lda $61
	jsr $bf7b
	ldx #<flp2
	ldy #>flp2
	jsr $bbd4
	lda #<flp1
	ldy #>flp1
	jsr $ba28
	jsr $b849
	jsr $bccc
	jsr $bc0c
	jsr f2fac
	jsr $bb12
ws3	ldy #0
	bit $66
	bpl ws6
	iny
ws6	jsr $bddf
	ldx #-1
	lda typ2
	cmp #64
	beq ws55
wsx	inx
	lda $100,x
	beq wsy
	cmp #"e"
	bne wsx
	beq ws55
wsy	ldx #-1
ws7	inx
	lda $100,x
	beq ws8
	cmp #"."
	bne ws7
	beq ws9
ws55	jmp ws00
ws8	sta $101,x
	lda #"."
	sta $100,x
ws9	stx dp
	lda typ1
	and #32
	beq wsa
	lda #","
	sta $100,x
wsa	ldy #-1
wsb	inx
	iny
	lda $100,x
	bne wsb
wbc	cpy an
	beq wbd
	lda #"0"
	sta $100,x
	iny
	inx
	bne wbc
wbd	lda #0
	sta $100,x
	ldx #-1
wbe	inx
	lda $100,x
	bne wbe
	stx lg
	lda dp
	beq wbg
	cmp #1
	bne wbf
	lda $100
	cmp #"-"
	bne wbf
wbg	ldx lg
	inc lg
	inx
wbi	lda !$ff,x
	sta $100,x
	dex
	cpx dp
	bne wbi
wbj	lda #"0"
	sta $100,x
	inc dp
wbf	lda typ1
	and #32
	beq ws0
	lda #3
	sta tmp
	ldy dp
nu2	dey
	bmi ws0
	dec tmp
	bpl nu2
	lda #3
	sta tmp
	iny
	sty tmp+1
	ldy lg
nu4	lda $100,y
	sta $101,y
	dey
	cpy tmp+1
	bcs nu4
	inc lg
	iny
	lda #"."
	sta $100,y
	bne nu2
ws0	lda an
	bne ws00
	ldx lg
	lda !$ff,x
	cmp #"."
	beq ws000
	cmp #","
	bne ws00
ws000	lda #0
	sta !$ff,x
ws00	ldx #-1
ws5	inx
	lda $100,x
	sta buf,x
	bne ws5
	rts
koord	lda x
	clc
	adc cx
	pha
	ora #192
	sta bs+40
	lda #175
	sta bs+41
	lda y
	clc
	adc cy
	tax
	jsr ascii
	lda dig
	ora #128
	sta bs+42
	lda dig+1
	ora #128
	sta bs+43
	lda dig+2
	ora #128
	sta bs+44
	lda #186
	sta bs+45
	pla
	tay
	dey
	dex
	jsr calc
	jsr rom
	ldy #0
	ldx #3
	lda fld+1
	beq ko1
	ldy #7
	lda (fld),y
	bmi ko2
	ldy #4
	.byt $24
ko2	iny
ko1	lda artt,y
	ora #128
	sta bs+47,x
	iny
	dex
	bpl ko1
	jsr clr2
	lda fld+1
	beq ko3
	ldy #9
	lda #0
	sta 211
ko4	lda (fld),y
	beq ko3
	sty ymk
	jsr sout
	bcs ko3
	ldy ymk
	iny
	bne ko4
ko3	rts
koin	lda #1
	ldx #5
	jsr input
	lda buf
	and #31
	bne ki1
ki2	jmp illko
ki1	cmp #sp+1
	bcs ki2
	sta ymk
	ldx #1
	lda buf+1
	cmp #"/"
	bne ki3
	inx
ki3	jsr wertx
	bcs ki2
	tax
	beq ki2
	cmp #za+1
	bcs ki2
	tax
	ldy ymk
	rts
los	jsr val
	jsr crsr
	jsr calc
	ldy #8
	lda fld+1
	beq lo4
lo1	iny
	lda (fld),y
	bne lo1
	iny
	tya
	clc
	adc fld
	sta tmp
	lda fld+1
	adc #0
	sta tmp+1
	ldy #0
lo2	lda (tmp),y
	sta (fld),y
	lda tmp
	cmp zei
	bne lo3
	lda tmp+1
	cmp zei+1
	beq lo6
lo3	inc tmp
	bne lo5
	inc tmp+1
lo5	inc fld
	bne lo2
	inc fld+1
	bne lo2
lo6	lda fld
	sta zei
	lda fld+1
	sta zei+1
lo4	jmp rom
input	sta tmp
	stx tmp+1
	ldx #0
	asl
	sta men
in1	stx xmk
	lda #0
	sta 204
in2	jsr gk
	ldx #2
	stx 205
in3	ldx 207
	bne in3
	inc 204
	ldx xmk
	cmp #20
	bne in4
	txa
	beq in1
	lda #<delt
	ldy #>delt
	jsr strout
	ldx xmk
	dex
	bpl in1
in4	cmp #13
	bne in5
	jsr m0
	sta buf,x
	rts
in5	cpx tmp+1
	bcs in1
	cmp #32
	bcc in1
	cmp #128
	bcc in6
	cmp #133
	bcc in1
	cmp #141
	bcc in8
	cmp #161
	bcc in1
	cmp #167
	bcc in6
	cmp #193
	bcc in1
	cmp #222
	beq in9
	cmp #219
	bcs in1
in6	ldy tmp
	bne in7
	cmp #48
	bcc in1
	cmp #58
	bcs in1
in7	jsr sout
	sta buf,x
	lda #0
	sta 212
	inx
	bne in1
in8	tay
	lda umlaut-133,y
	bne in6
in9	lda #-1
	bne in6
input2	lda #c2
	sta 646
	jsr clr2
	stx 214
	lda #0
	sta 211
	jmp 58732
clr2	ldx #2
	jmp 59903
wert	ldx #0
wertx	lda #0
uw1	sta tmp
	inx
	lda buf-1,x
	beq uw2
	and #15
	sta tmp+1
	asl tmp
	bcs uw3
	lda tmp
	asl
	bcs uw3
	asl
	bcs uw3
	adc tmp
	bcs uw3
	adc tmp+1
	bcc uw1
uw3	rts
uw2	lda tmp
	clc
	rts
init	sei
	jsr 65418
	jsr 58451
	jsr $ffe7
	jsr 65409
	sei
	lda #<irq
	ldy #>irq
	sta 788
	sty 789
	lda #<numneu
	ldy #>numneu
	sta $30a
	sty $30b
	lda #<errneu
	ldy #>errneu
	sta $300
	sty $301
	lda #<info
	ldy #>info
	sta 792
	sty 793
	ldx #0
	stx 56576
	stx men
	stx 157
	lda #128
	sta 650
	lda #61
	sta 53272
	lda #204
	sta 648
	jsr $e544
	lda #c1
	sta 53280
	sta 53281
	lda #c2
	sta 646
	ldy #0
	sty tmp
	ldx #216
	stx tmp+1
	ldx #4
ci	sta (tmp),y
	iny
	bne ci
	inc tmp+1
	dex
	bne ci
	cli
	ldx #4
	ldy #0
	sty tmp
	sty tmp2
	jsr ram
	lda #>zs
	sta tmp+1
	lda #>zs+$400
	sta tmp2+1
nw1	lda (tmp),y
	eor #-1
	sta (tmp2),y
	iny
	bne nw1
	inc tmp+1
	inc tmp2+1
	dex
	bne nw1
	lda #<mem1
	ldy #>mem1
	sta tmp
	sty tmp+1
	ldx #za
	ldy #0
nw2	lda tmp
	sta mem2,y
	lda tmp+1
	sta mem2+za,y
	iny
	lda tmp
	clc
	adc #sp*2
	sta tmp
	bcc nw6
	inc tmp+1
nw6	dex
	bne nw2
	lda #32
	sta dig
	sta dig+1
	lda #48
	sta dig+2
	ldy #0
nw5	lda dig
	sta qq3,y
	lda dig+1
	sta qq3+256,y
	lda dig+2
	sta qq3+512,y
	inc dig+2
	lda dig+2
	cmp #"9"+1
	bcc nw8
	lda #48
	sta dig+2
	lda dig+1
	cmp #" "
	bne nw7
	lda #48
	sta dig+1
nw7	inc dig+1
	lda dig+1
	cmp #"9"+1
	bcc nw8
	lda #48
	sta dig+1
	lda dig
	cmp #" "
	bne nw9
	lda #48
	sta dig
nw9	inc dig
nw8	iny
	bne nw5
	jsr global
	jmp val
global	ldx #1
	stx x
	stx y
	dex
	stx cx
	stx cy
	rts
new	ldx #0
	stx mea
	stx dat
	stx show
	inx
	stx auto
	stx bar
	lda #34
	sta de1
	lda #91
	sta de2
	lda #43
	sta de3
	ldx #sp-1
	lda #11
n	sta blt,x
	dex
	bpl n
	bmi global
sure	lda #<t2
	ldy #>t2
	jsr strout
	lda #3
	sta men
sr1	jsr getk
	cmp #"\x85"
	beq sr2
	cmp #"\x88"
	bne sr1
sr2	pha
	jsr out
	pla
	cmp #"\x85"
sr3	rts
testnum	ldy #7
	lda (fld),y
	bmi sr3
	lda #<td
	ldy #>td
	jmp ero
holpos	lda #8
	sta men
hp1	jsr getk
	cmp #"\x88"
	beq hp2
	cmp #"\x85"
	beq hp3
	cmp #"\x86"
	beq hp4
	cmp #"\x87"
	bne hp1
	lda #0
	.byt $2c
hp3	lda #32
	.byt $2c
hp4	lda #16
	clc
	sta tmp
hp2	rts
holzif	lda #9
	sta men
hp5	jsr getk
	ldx #-1
	cmp #"\x88"
	beq hp2
	cmp #"\x87"
	beq hp6
	cmp #"\x86"
	beq hp7
	cmp #"\x85"
	bne hp5
	lda #<t6
	ldy #>t6
	jsr strout
	lda #0
	sta 204
	jsr getk
	ldx #1
	stx 204
	cmp #"0"
	bcs hp8
hp9	jmp daz
hp8	cmp #"9"+1
	bcs hp9
	and #15
	tax
	lda #128
	.byt $2c
hp6	lda #0
	.byt $2c
hp7	lda #64
	clc
	sta tmp
	rts
holcol	lda #<te
	ldy #>te
	jsr strout
	ldx #2
	lda #1
	jsr input
	jsr wert
	bcs hp9
	cmp #16
	bcs hp9
	cmp #c1
	beq hp9
	sta tmp
ta1	rts
ther	jsr tanw
	jsr crsr
	jsr calc
	pha
	jsr rom
	pla
	bne ta1
	lda #<ta
	ldy #>ta
th3	jmp ero
tanw	lda mea
	bne ta1
	lda #<ti
	ldy #>ti
	bne th3
tend	lda zei+1
	cmp #>mee-50
	bcc ta1
	bne th4
	lda zei
	cmp #<mee-50
	bcc ta1
th4	lda #<tj
	ldy #>tj
	bne th3
start	jsr init
	lda #<tt
	ldy #>tt
	jsr strout
	jsr out
	lda #<cc
	ldy #>cc
	jsr strout
	jsr getk
info	jsr free
	jsr out
	jsr dout
main	lda #0
	sta rf
	sta 199
	ldx #246
	txs
	jsr cuca
	jsr koord
	jsr cursor
ma3	lda #1
	sta men
	jsr getk
	dec men
	ldx #menadr-mentxt-1
ma1	cmp mentxt,x
	beq ma2
	dex
	bpl ma1
	bmi ma5
ma2	txa
	asl
	tax
	lda menadr,x
	sta tmp
	lda menadr+1,x
	sta tmp+1
	jsr cursor
	lda #0
	sta flg
	jsr ma4
	jmp main
ma5	cmp #222
	beq ma6
	cmp #33
	bcc ma3
	cmp #96
	bcs ma3
ma6	pha
	jsr cursor
	pla
	jsr buchst
	jmp main
ma4	jmp (tmp)
home	lda cx
	ora cy
	bne cb1
	jsr global
	jmp scroll
unhom	lda #0
	sta cx
	lda #19
	sta cy
	lda #za-19
	sta y
	lda #sp
	sta x
scroll	jsr out
cb5	jmp cuca
cb1	lda #0
	sta cx
	sta cy
	beq cb5
down	lda cy
	cmp #19
	bcc cb2
	lda y
	cmp #za-19
	bcs cb4
	inc y
	bne scroll
cb2	inc cy
cb4	rts
up	lda cy
	beq cb6
	dec cy
	rts
cb6	lda y
	cmp #2
	bcc cb4
	dec y
	bne scroll
left	lda cx
	bne cb7
	lda x
	cmp #2
	bcc cb4
	dec x
	bne scroll
cb7	dec cx
	bpl cb5
right	lda x
	cmp #sp
	bcs cb4
	adc cx
	cmp #sp
	bcs cb4
rt	inc cx
	jsr cuca
	lda bx
	clc
	adc bl
	cmp #41
	bcc cb3
	dec cx
	dec cx
	inc x
	inc flg
	bne rt
cb3	lda flg
	beq cb4
	bne scroll
space	jsr datain
	pha
	jsr inzei
	lda de3
parin	jsr inzei
	ldx #-1
sc2	inx
	lda buf,x
	jsr inzei
	cmp #0
	bne sc2
	jsr inzei
	jsr free
	pla
	beq sc4
	lda auto
	beq sc4
	jsr rechne
sc4	jmp out
datain	jsr tend
	jsr input2
	lda #1
	ldx #38
	jsr input
	txa
	beq sc3
	jsr los
	ldy #0
	lda cy
	clc
	adc y
	jsr inzei
	lda cx
	clc
	adc x
	jsr inzei
	lda #0
	jsr inzei
	jsr inzei
	jsr inzei
	jsr inzei
	jsr inzei
sc3	rts
buchst	sta 631
	lda #1
	sta 198
	jsr datain
	lda de1
	and #63
	ora #128
	pha
	jsr inzei
	lda de2
	jmp parin
rechne	lda #-1
r	sta iz
	lda #<t1
	ldy #>t1
	sty rf
	jsr strout
ir1	ldx iz
	cpx #-1
	beq ir2
	lda qq3,x
	sta bs+117
	lda qq3+256,x
	sta bs+118
	lda qq3+512,x
	sta bs+119
	lda #"\x09"
	sta bs+115
	lda #"="
	sta bs+116
ir2	lda #0
	sta lin
	sta af
re1	lda #0
	sta spa
re2	ldx lin
	ldy spa
	jsr calc
	beq re4
	ldy #7
	lda (fld),y
	bpl re4
	and #64
	bne ir7
	sty af
	beq ir6
ir7	ldy #6
	ldx #4
ir8	lda (fld),y
	sta flp3,x
	dey
	dex
	bpl ir8
ir6	ldy #9
	ldx #0
re5	lda (fld),y
	sta $200,x
	inx
	iny
	cmp #0
	bne re5
	jsr rom
	ldx #0
	stx $7a
	jsr $a57c
	lda #0
	sta nbf
	ldy #2
	sta 122
	sty 123
	jsr 121
	jsr $ad8a
	lda nbf
	bne re6
	lda #2
	clc
	adc fld
	tax
	lda #0
	adc fld+1
	tay
	jsr $bbd4
	lda af
	bne ir9
	ldy iz
	iny
	beq ir9
	lda #<flp3
	ldy #>flp3
	jsr $bc5b
	beq ir9
	sta af
ir9	ldy #7
	lda (fld),y
	ora #64
re4	sta (fld),y
	jsr rom
	inc spa
	lda spa
	cmp #sp
	bcc re22
	inc lin
	lda lin
	cmp #za
	bcc re11
	lda #0
	sta rf
	beq ir3
re6	ldy #7
	sty af
	lda (fld),y
	and #191
	jmp re4
ir3	inc iz
	bne ir4
ir5	jmp clr2
ir4	jsr 65508
	cmp #"\x88"
	beq ir5
	cmp #"\x03"
	beq ir5
	lda af
	beq ir5
	jmp ir1
re22	jmp re2
re11	jmp re1
dorech	jsr tanw
	lda #13
	sta men
dc1	jsr getk
	cmp #"\x88"
	bne dc2
	rts
dc2	cmp #"\x85"
	beq dc3
	cmp #"\x86"
	bne dc1
	lda #1
	.byt $2c
dc3	lda #-1
	ldx #0
	stx men
	jsr r
	jmp out
numneu	lda #0
	sta $d
	jsr 115
	cmp #"a"
	bcs nn1
nn2	cmp #"$"
	beq nn8
	cmp #"%"
	beq nn9
	cmp #"["
	beq fi1
	jsr 121
	jmp $ae8d
nn1	cmp #"z"+1
	bcs nn2
	jsr go3
	lda #1
	jsr $a3fb
	ldx tmp
	dex
	lda fld
	pha
	lda fld+1
	pha
	jsr calc
	jsr rom
	lda fld+1
	beq nn7
	ldy #7
	lda (fld),y
	and #192
	cmp #192
	bne nn7
	lda fld
	clc
	adc #2
	tax
	lda fld+1
	adc #0
	tay
	txa
	jsr $bba2
nn6	pla
	sta fld+1
	pla
	sta fld
	jmp 121
nn7	lda #1
	sta nbf
	bne nn6
fi1	jmp fi2
nn9	jsr clrfac
	bmi nng
nn8	jsr clrfac
nna	jsr 115
	bcc nnb
	cmp #"a"
	bcc nnc
	cmp #"g"
	bcs nnc
	sbc #6
nnb	sec
	sbc #"0"
	sta tmp
	lda $61
	beq nnd
	clc
	adc #4
	bcs nne
	sta $61
nnd	lda tmp
	beq nna
	jsr $bd7e
	jmp nna
nng	jsr 115
	cmp #"2"
	bcs nnc
	cmp #"0"
	bcc nnc
	sbc #"0"
	sta tmp
	lda $61
	beq nnf
	inc $61
	beq nne
nnf	lda tmp
	beq nng
	jsr $bd7e
	jmp nng
nnc	jmp 121
nne	jmp $b97e
getko	jsr 115
	cmp #"a"
	bcs go1
illko	lda #<t7
	ldy #>t7
fi5	jmp ero
go1	cmp #"z"+1
	bcs illko
go3	sbc #"@"
	tay
	lda #0
go4	sta tmp
	jsr 115
	bcs go5
	and #15
	sta tmp+1
	asl tmp
	bcs illko
	lda tmp
	asl
	bcs illko
	asl
	bcs illko
	adc tmp
	bcs illko
	adc tmp+1
	bcs illko
	bcc go4
go5	ldx tmp
	beq illko
	dex
	cpx #za
	bcs illko
	rts
fib	jmp $af08
fi2	jsr getko
	sty y1
	stx x1
	jsr 121
	ldx #5
fi3	cmp optab,x
	beq fi4
	dex
	bpl fi3
	lda #<tk
	ldy #>tk
	bne fi5
fi4	stx nr
	jsr getko
	sty y2
	stx x2
	cmp #"]"
	bne fib
	lda #2
	jsr $a3fb
	lda fld
	pha
	lda fld+1
	pha
	lda spa
	pha
	ldy #0
	sty az
	sty az+1
	ldx #4
fi6	tya
	sta flp1,x
	lda fmax,x
	sta flp2,x
	dex
	bpl fi6
	lda nr
	cmp #3
	bne fix
	lda flp2+1
	eor #128
	sta flp2+1
fix	cmp #5
	bne fi7
	lda #129
	sta flp1
fi7	lda y1
	sta spa
fi8	ldy spa
	ldx x1
	jsr calc
	jsr rom
	lda fld+1
	beq fid
	ldy #7
	lda (fld),y
	and #192
	cmp #192
	bne fid
	inc az
	bne fia
	inc az+1
fia	lda nr
	cmp #2
	bcs fic
	jsr f1fac
	lda fld
	clc
	adc #2
	tax
	lda fld+1
	adc #0
	tay
	txa
	jsr $b867
fiy	ldx #<flp1
	ldy #>flp1
	jsr $bbd4
	jmp fid
fiz	jsr f1fac
	lda fld
	clc
	adc #2
	tax
	lda fld+1
	adc #0
	tay
	txa
	jsr $ba28
	jmp fiy
fic	cmp #5
	beq fiz
	cmp #4
	bcs fid
	jsr f2fac
	lda fld
	clc
	adc #2
	tax
	lda fld+1
	adc #0
	tay
	txa
	jsr $bc5b
	ldx nr
	cpx #3
	beq fif
	cmp #1
	beq fig
	bne fid
fif	cmp #-1
	bne fid
fig	ldy #6
	ldx #4
fih	lda (fld),y
	sta flp2,x
	dey
	dex
	bpl fih
fid	inc spa
	lda spa
	cmp y2
	bcc fi88
	beq fi88
	inc x1
	lda x1
	cmp x2
	bcc fi77
	beq fi77
	pla
	sta spa
	pla
	sta fld+1
	pla
	sta fld
	lda nr
	beq fij
	cmp #4
	bne fii
	ldx az
	lda az+1
	jsr axfac
	jmp 115
fi88	jmp fi8
fi77	jmp fi7
fij	jsr f1fac
	jmp 115
fii	cmp #5
	beq fij
	cmp #1
	bne fik
	lda az
	ora az+1
	bne fil
	lda #<tl
	ldy #>tl
	jmp ero
fil	ldx az
	lda az+1
	jsr axfac
	lda #<flp1
	ldy #>flp1
	jsr $ba8c
	jsr $bb12
	jmp 115
fik	jsr f2fac
	jmp 115
errneu	txa
	stx errn
	asl
	tax
	lda $a326,x
	ldy $a327,x
	bne eroz
ero	ldx #0
	stx errn
eroz	sta 34
	sty 35
	jsr $ffe7
	jsr input2
	ldy #0
	sty tmp
	sty $13
	sty 198
	sty 199
er1	lda (34),y
	pha
	and #127
	ldx tmp
	bne er5
	ora #128
	sta tmp
er5	jsr $ffd2
	iny
	pla
	bpl er1
	ldx errn
	cpx #11
	bne er3
	lda #$6a
	ldy #$a3
	jsr $ab1e
er3	lda rf
	beq er4
	lda #<inf
	ldy #>inf
	jsr strout
	lda spa
	clc
	adc #"a"
	jsr sout
	lda #"/"
	jsr sout
	ldx lin
	inx
	txa
	jsr ascii
	lda dig
	jsr sout
	lda dig+1
	jsr sout
	lda dig+2
	jsr sout
er4	lda #0
	ldx #24
er6	sta 54272,x
	dex
	bpl er6
	lda #15
	sta 54296
	lda #80
	sta 54273
	lda #240
	sta 54278
	lda #17
	sta tmp
	ldx #0
	stx tmp+1
	sta 54276
er7	lda 198
	bne er8
	dex
	cpx #200
	bne er7
	ldx #0
	dec tmp+1
	bne er7
	lda tmp
	eor #16
	sta tmp
	sta 54276
	ldy #39
erz	lda 55376,y
	eor #10
	sta 55376,y
	dey
	bpl erz
	bmi er7
er8	lda #16
	sta 54276
	lda #0
	sta 198
	sta 54296
	jmp info
ende	jsr sure
	bne en1
	jmp ($fffc)
en1	rts
goto	lda #<t8
	ldy #>t8
	jsr strout
	jsr koin
	sty x
	lda #0
	sta cx
	cpx #za-18
	bcc gt1
	lda #za-19
	sta y
	txa
	sbc #za-19
	sta cy
	bpl gt2
gt1	sta cy
	stx y
gt2	jmp scroll
darst	lda #4
	sta men
	jsr clr2
da1	jsr getk
	cmp #"\x8c"
	beq en1
	cmp #"\x85"
	beq da2
	cmp #"\x89"
	beq da3
	cmp #"\x88"
	beq da44
	cmp #"\x8b"
	beq da9
	cmp #"\x8a"
	beq ty1
	cmp #"\x87"
	beq lo
	cmp #"\x86"
	bne da1
	jmp glob
ty1	jmp ty2
da44	jmp da4
da2	lda #<t4
	ldy #>t4
	jsr strout
	lda auto
	eor #1
	sta auto
	jmp aa
da3	lda #<t5
	ldy #>t5
	jsr strout
	lda show
	eor #1
	sta show
	jsr aa
	jmp out
da9	lda bar
	eor #1
	sta bar
	jmp out
lo	jsr ther
dab	lda #5
	sta men
dac	jsr getk
	cmp #"\x8c"
	beq dae
	cmp #"\x88"
	beq dad
	cmp #"\x87"
	beq daf
	cmp #"\x85"
	beq dah
	cmp #"\x86"
	bne dac
	lda #<tc
	ldy #>tc
	jsr strout
	jsr testnum
	lda (fld),y
	eor #32
	sta (fld),y
	and #32
	jsr aa
	jmp out
daf	jsr holpos
	bcs dab
	ldy #8
	lda (fld),y
	and #207
	ora tmp
	sta (fld),y
dag	jmp out
dad	jsr testnum
	jsr holzif
	bcs dab
	ldy #8
	lda (fld),y
	and #63
	ora tmp
	sta (fld),y
	txa
	bmi dag
	dey
	sta tmp
	lda (fld),y
	and #224
	ora tmp
	sta (fld),y
	bne dag
dah	jsr holcol
	ldy #8
	lda (fld),y
	and #240
	ora tmp
	sta (fld),y
	jmp out
dae	jmp darst
da4	lda #6
	sta men
da5	jsr getk
	cmp #"\x88"
	beq dae
	cmp #"\x85"
	beq da6
	cmp #"\x86"
	bne da5
da6	sta tmp2
	jsr m0
	lda #<t3
	ldy #>t3
	jsr strout
	lda #0
	ldx #2
	jsr input
	jsr wert
	bcs daz
	tax
	beq daz
	cmp #30
	bcs daz
	ldx tmp2
	cpx #133
	bne da7
	pha
	jsr crsr
	pla
	sta blt,y
	jmp out
da7	ldy #sp-1
da8	sta blt,y
	dey
	bpl da8
	jmp out
daz	lda #<tb
	ldy #>tb
	jmp ero
glob	lda #10
	sta men
	ldx #-1
	stx m
	stx m+1
	inx
	stx m+2
	stx m+3
gb1	jsr getk
	cmp #"\x88"
	beq dae
	cmp #"\x85"
	beq gb2
	cmp #"\x86"
	beq gb3
	cmp #"\x87"
	bne gb1
	lda #192
	.byt $2c
gb2	lda #64
	.byt $2c
gb3	lda #128
	sta tmp2
	and #128
	sta tmp2+1
	lda #5
	sta men
gb4	jsr getk
	cmp #"\x8c"
	beq glob
	cmp #"\x88"
	beq gb5
	cmp #"\x87"
	beq gb6
	cmp #"\x85"
	beq gb7
	cmp #"\x86"
	bne gb4
	lda #<tc
	ldy #>tc
	jsr strout
	lda #<tf
	ldy #>tf
	jsr strout
	lda #0
	sta men
gb9	jsr getk
	cmp #"n"
	beq gb8
	cmp #"j"
	bne gb9
	lda #32
	.byt $2c
gb8	lda #0
	sta m+2
	lda #223
	sta m
	bne okglo
gb6	jsr holpos
qlob	bcs glob
	sta m+3
	lda #207
	bne og0
gb5	jsr holzif
	bcs qlob
	sta m+3
	txa
	bmi gb5a
	stx m+2
	lda #224
	sta m
gb5a	lda #63
	bne og0
gb7	jsr holcol
	sta m+3
	lda #240
og0	sta m+1
okglo	jsr sure
	beq og1
	rts
og1	jsr input2
	lda #$65
	jsr $e18f
	lda #<mea
	ldy #>mea
	sta fld
	sty fld+1
og2	ldy #0
	lda (fld),y
	beq og3
	lda tmp2
	cmp #192
	beq og4
	ldy #7
	lda (fld),y
	iny
	and #128
	cmp tmp2+1
	bne og6
og4	ldy #7
	lda (fld),y
	and m
	ora m+2
	sta (fld),y
	iny
	lda (fld),y
	and m+1
	ora m+3
	sta (fld),y
og6	iny
	lda (fld),y
	bne og6
	iny
	tya
	clc
	adc fld
	sta fld
	bcc og2
	inc fld+1
	bne og2
og3	ldx tmp2
	bpl og7
	lda de1
	and m
	ora m+2
	sta de1
	lda de2
	and m+1
	ora m+3
	sta de2
og7	txa
	and #64
	beq og8
	lda de3
	and m+1
	ora m+3
	sta de3
og8	jmp out
day	lda #<t9
	ldy #>t9
	jsr strout
	jsr m0
	lda #1
	ldx #13
	jsr input
	txa
	beq et3
et4	lda buf,x
	sta dat,x
	dex
	bpl et4
dout	lda #1
	sta 199
	sta 214
	lda #14
	sta 211
	jsr 58732
	ldx #0
dt1	lda dat,x
	beq dt2
	jsr $ffd2
	inx
	bne dt1
dt2	lda #32
dt3	ldx 211
	cpx #68
	bcs et3
	jsr $ffd2
	bcc dt3
et3	rts
ty2	jsr ther
ty4	ldy #7
	lda (fld),y
	and #191
	eor #128
	sta (fld),y
	bpl ty5
	lda auto
	beq ty5
	jsr rechne
ty5	jmp out
clr	lda #7
	sta men
	jsr clr2
cr1	jsr getk
	cmp #"\x88"
	bne cr2
cr4	rts
cr2	cmp #"\x85"
	beq cr3
	cmp #"\x86"
	bne cr1
	jsr sure
	bne cr4
	jsr new
	jmp cr5
cr3	jsr los
cr5	jmp info
disk	lda #11
	sta men
	jsr clr2
di1	jsr getk
	cmp #"\x8c"
	bne di2
di3	rts
di2	cmp #"\x88"
	beq di5
	cmp #"\x85"
	beq di6
	cmp #"\x86"
	beq di4
	cmp #"\x87"
	bne di1
	ldx #<dirn
	ldy #>dirn
	lda #1
	jsr $ffbd
	lda #8
	sta $ba
	lda #$60
	sta $b9
	jsr $f3d5
	lda $ba
	jsr $ffb4
	lda $b9
	jsr $ff96
	lda #0
	sta 144
	jsr dwind
	ldy #3
l1	sty tmp
	jsr $ffa5
	sta tmp+1
	ldy 144
	bne l4
	jsr $ffa5
	ldy 144
	bne l4
	ldy tmp
	dey
	bne l1
	ldx tmp+1
	jsr $bdcd
	jsr $ab3f
l3	jsr $ffa5
	ldx 144
	bne l4
	tax
	beq l2
	jsr $ffd2
	bcc l3
l2	jsr $aad7
	lda #6
	sta 211
	lda 214
	cmp #22
	bcc l5
	jsr fort
l5	ldy #2
	bne l1
di5	beq di55
di6	jmp di66
di4	jmp di44
l4	lda #12
	sta men
	jsr $f642
	jsr getk
	jmp out
fort	lda #12
	sta men
l6	jsr getk
	cmp #"\x85"
	beq dwind
	cmp #"\x88"
	bne l6
	pla
	pla
	jsr $f642
	jmp out
dwind	jsr m0
	lda #<wt4
	ldy #>wt4
	jsr strout
	lda #16
	sta tmp
dw1	lda #<wt5
	ldy #>wt5
	jsr strout
	dec tmp
	bne dw1
	lda #<wt6
	ldy #>wt6
	jmp strout
di55	jsr input2
	lda #<tg
	ldy #>tg
	jsr strout
	jsr m0
	ldx #27
	lda #1
	jsr input
	txa
	ldx #<buf
	ldy #>buf
	.byt $2c
ek	lda #0
	jsr $ffbd
	lda #15
	tay
	ldx #8
	jsr $ffba
	jsr $ffc0
	ldx #15
	jsr $ffc6
	jsr input2
	lda #0
	sta tmp
ek1	jsr 65508
	ldx tmp
	bne ek2
	sta tmp
ek2	jsr $ffd2
	cmp #13
	bne ek1
	jsr $ffcc
	lda #15
	jsr $ffc3
	lda tmp
	cmp #"0"
	bne ek3
	jmp getk
ek3	jmp er4
getnam	jsr input2
	lda #<th
	ldy #>th
	jsr strout
	ldx #13
	lda #1
	jsr input
	txa
	beq gn1
	clc
	adc #3
	ldx #<hn
	ldy #>hn
	jsr $ffbd
	lda #"t"
	sta hn
	lda #"r"
	sta hn+1
	lda #"/"
	sta hn+2
	ldx #8
	jmp $ffba
gn1	rts
di44	jsr tanw
	jsr getnam
	beq gn1
	jsr val
	ldx zei
	ldy zei+1
	inx
	bne nh
	iny
nh	lda #<blt
	sta tmp
	lda #>blt
	sta tmp+1
	lda #tmp
	jsr $ffd8
	jmp ek
di66	jsr getnam
	beq gn1
	ldx #<blt
	ldy #>blt
	lda #0
	sta $b9
	jsr $ffd5
	jsr ek
	jmp info
print	jsr tanw
	ldx #4
	lda #1
	ldy #7
	jsr $ffba
	jsr $ffc0
	ldx #1
	jsr $ffc9
	jsr $aad7
	lda 144
	bpl pi1
	lda #<tm
	ldy #>tm
	jmp ero
pi1	lda #<fax1
	ldy #>fax1
	jsr $ab1e
	lda #<dat
	ldy #>dat
	jsr $ab1e
	jsr $aad7
	ldx #60
	lda #"-"
pi2	jsr $ffd2
	dex
	bne pi2
	jsr $aad7
	jsr $aad7
	lda #<mea
	ldy #>mea
	sta fld
	sty fld+1
pi3	ldy #0
	sty lg
	lda (fld),y
	bne pi4
	jsr $aad7
	jsr $ffcc
	lda #1
	jmp $ffc3
pi4	tax
	iny
	lda (fld),y
	ora #192
	jsr $ffd2
	lda #"/"
	jsr $ffd2
	lda qq3,x
	jsr $ffd2
	lda qq3+256,x
	jsr $ffd2
	lda qq3+512,x
	jsr $ffd2
	jsr $ab3f
	jsr $ab3f
	ldy #7
	lda (fld),y
	bmi pi5
	inc lg
	lda #34
	.byt $2c
pi5	lda #32
	jsr $ffd2
	ldy #9
pi6	lda (fld),y
	beq pi7
	cmp #161
	bcc pim
	cmp #167
	bcc pin
pim	cmp #174
	beq pio
	cmp #64
	beq pip
piq	jsr $ffd2
	iny
	bne pi6
pi7	iny
	tya
	clc
	adc fld
	sta fld
	bcc pi8
	inc fld+1
pi8	lda lg
	beq pi9
	lda #34
	jsr $ffd2
pi9	jsr $aad7
	jmp pi3
pio	lda #"s"
	jsr $ffd2
	bne piq
pip	lda #"("
	jsr $ffd2
	lda #"c"
	jsr $ffd2
	lda #")"
	bne piq
pin	tax
	lda umreal-161,x
	jsr $ffd2
	lda #"e"
	bne piq
; ...............